! Simple tracking test for LHC beam screen.
! tstTrack_ap_lhcscreen.madx

option,-echo,-info,-warn;

! **********  Apertures introduced **********
qf:multipole, knl={0,-0.0}, apertype= lhcscreen, aperture={0.000707,0.002,0.001};! V
qd:multipole, knl={0,-0.0}, apertype= lhcscreen, aperture={0.002,0.000707,0.001};! H
!--------------------------------------------  syntax : hlimit,vlimit,radius
endmk:marker;

!***   NOTE : two limits are given for the flat part. If one is larger than the 
!***   radius (last parameter) it will not appear (LHC case)

! ********** Define sequences
smachd: sequence, l= 2.0; 
qd, at= 1.00;
endmk, at= 2.0;
endsequence;

smachf: sequence, l= 2.0; 
qf, at= 1.00;
endmk, at= 2.0;
endsequence;

! ********** Define beam and use the sequence with it 
beam, sequence= smachd, particle= proton, energy= 450;
use,  sequence= smachd;

! ********** Track 10000 particles
track, onepass, onetable, file= "out_d", aperture, dump;
  n=0;  
  while(n<20) {
     n= n+1; 
     start, x= -0.001+0.002*ranf(), 
            y= -0.001+0.002*ranf(),
            px= 0, py= 0;
  }
  run, turns= 1; 
endtrack;

! ********** Define beam and use the sequence with it 
! This time with errors
beam, sequence= smachf, particle= proton, energy= 450;
use,  sequence= smachf;

select, flag= error, class= multipole;  
ealign, dx= 0.0002, dy= 0.000; ! ,arex=-0.0003,arey=-0.0002;

! ********** Track 10000 particles
track, onepass, onetable, file= "out_f", aperture, dump;
  n=0;  
  while(n<20) {
     n= n+1; 
     start, x= -0.001+0.002*ranf(), 
            y= -0.001+0.002*ranf(),
            px= 0, py= 0;
  }
  run, turns= 1; 
endtrack;


return;